progressbar / how to show progression in long running operation?

Hi Ronald,

In this case, you can log the job progress into a db table. In your formspider application, create a datasource from this log table (named "LOG1" in the example below). When you run your job, start a Formspider timer (named "jobProgress" in the example below) which regularly queries (with an interval of 10 seconds for example) your log datasource in its timerExpired event. You can bind this log datasource to a Formspider grid to display the progress.

As an example, the procure which runs your job may be as following:

procedure runJob is
  v_job_id number;
  v_jobName_tx varchar2(255);
begin
  -- generate an unique job name
  v_jobName_tx := dbms_scheduler.generate_job_name;
  api_session.add('jobName', v_jobName_tx);
  -- start the timer
  api_timer.starttimer('jobProgress'); 
  -- create and run the job
  dbms_scheduler.create_job(job_name        => v_jobName_tx,
                            job_type        => 'PLSQL_BLOCK',
                            job_action      => 'BEGIN job1; END;',
                            start_date      => sysdate,
                            repeat_interval => null,
                            end_date        => sysdate+1,
                            enabled         => true,
                            auto_drop       => true);
end;

Then, you can call the following procedure on timerExpired event of the "jobProgress" timer:

procedure timerExpired is
  v_isJobRunning_yn varchar2(1);
  v_jobName_tx varchar2(255);
begin
  v_jobName_tx := api_session.getvaluetx('jobName');
  -- if a running job exists
  if v_jobName_tx is not null then
    -- check whether this job is still running or not
    begin
      select 'Y' into v_isJobRunning_yn from dual
      where exists (select 1 
                    from USER_SCHEDULER_RUNNING_JOBS 
                    where job_name = v_jobName_tx
                  );
    exception 
      when no_data_found then
        v_isJobRunning_yn := 'N';
    end;

    -- query job logs from your custom table
    api_datasource.executequery('LOG1');

    -- if the job is completed remove the session variable
    if v_isJobRunning_yn = 'N' then
      api_session.remove('jobName');
    end if;
  end if;
end;

Hope this helps,
Ibrahim